**Triple-F Health Club**

Student Instructions

Triple-F Health Club (Family, Fitness, and Fun) is a not-for-profit family-oriented health club. The club's board of directors is developing plans to acquire more equipment and to expand club facilities. The board plans to purchase about $25,000 new equipment each year and wants to establish a fund to purchase the adjoining property in four or five years. The adjoining property has a market value of about $300,000.

The club manager, Luca Pacioli, is concerned that the board has unrealistic goals in light of the club's recent financial performance. He has sought the help of a club member (you!!! a UCF graduate) with a superior education to assist him in preparing a report to the board supporting his concerns.

While attending UCF you learned about the need for cash budgeting and that much of the data needed for the cash budget is plagued by random variables. For example how many members will we have in 2018 and 2019? How many of our members will enroll in additional lessons and classes, what will the costs be for towels and utilities, etc. Will we have enough cash generated from operations to meet our cash obligations and will we have enough cash for the planned equipment and land purchases in the future.

But you are undeterred because you know about Monte Carlo Simulation - where you can algebraically model the uncertainty of everything that goes into the cash budget using Excel and your knowledge of algebra and statistics.

With your knowledge of Monte Carlo Simulation you are confident you can predict the uncertainty of the cash flow at the end of next year and provide the Board of Directors with superior information about the cash flow in the future and make decisions with greater confidence.

You have reviewed the club's records and spoken to various employees to determine the following information.

You have studied the membership for this year and the past seven years in order to project the membership for the next two years. You have decided to use Excel’s "Forecast Sheet" feature to forecast the next two years membership.

Exhibit 1

|  |  |
| --- | --- |
| Year | Actual Members |
| 2010 | 5,833 |
| 2011 | 6,409 |
| 2012 | 7,161 |
| 2013 | 6,519 |
| 2014 | 7,443 |
| 2015 | 8,423 |
| 2016 | 7,250 |
| 2017 | 7,996 |

The board has been considering increasing the fee for the annual membership. They could leave the annual membership fee at $45 or increase it to $50 or even to $55. Use an empirical pdf for this variable in your MCS model

Exhibit 2

|  |  |  |
| --- | --- | --- |
|  | Amount | Probability |
| Current membership fee: | $45.00 | 10% |
| Increase to most likely: | $50.00 | 50% |
| Increase to a maximum of: | $55.00 | 40% |

For the "Lesson and class fees" you have decided to rely on the average percentage (percentage of total fees) over the past seven years. For the "Miscellaneous" you realize it is truly miscellaneous and is an arbitrary amount, so you have estimated the following for next year after consultation with Luca Pacioli.

Exhibit 3

|  |  |  |  |
| --- | --- | --- | --- |
|  | Minimum | Mode | Maximum |
| Lesson and class fees | 55% | 63% | 70% |
|  | Minimum | Maximum |  |
| Miscellaneous | $2,000 | $3,000 |  |

The board plans to purchase new exercise equipment next year – they are not certain of the cost but they have the following best estimates:

Exhibit 4

|  |  |
| --- | --- |
| Minimum expected to pay | $25,000 |
| Most likely will pay | $30,000 |
| Maximum expected to pay | $32,000 |

You have been running some regression analysis of the membership and the various costs over this year and the past seven years to determine how much cost is fixed and how much is variable. The following data was used for the regression analysis.

Exhibit 5

|  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- |
| Year | Actual Members | Manager's salary and benefits | Regular employees' wages and benefits | Lesson and class employees' wages and benefits | Towels and supplies | Utilities (heat and light) | Mortgage interest | Miscellaneous |
| 2010 | 5,833 | $43,300 | $141,700 | $137,000 | $11,300 | $15,200 | $35,100 | $1,250 |
| 2011 | 6,409 | $43,300 | $137,200 | $138,400 | $12,100 | $14,700 | $35,100 | $1,390 |
| 2012 | 7,161 | $48,000 | $141,700 | $145,600 | $13,500 | $15,800 | $35,100 | $1,370 |
| 2013 | 6,519 | $48,900 | $142,500 | $146,200 | $13,200 | $16,500 | $35,100 | $1,450 |
| 2014 | 7,443 | $53,100 | $162,100 | $149,000 | $14,000 | $16,600 | $35,100 | $1,540 |
| 2015 | 8,423 | $54,100 | $177,600 | $156,200 | $13,800 | $18,500 | $35,100 | $1,610 |
| 2016 | 7,250 | $51,900 | $166,600 | $153,200 | $13,700 | $18,100 | $35,100 | $1,800 |
| 2017 | 7,996 | $56,000 | $160,000 | $150,000 | $14,500 | $18,200 | $35,100 | $2,000 |

The mortgage details are:

Exhibit 6

|  |  |
| --- | --- |
| Outstanding mortgage balance | $360,000 |
| Annual principal payment, November 1st every year | $30,000 |
| Interest rate on unpaid balance | 9.00% |

**Your Workbook**

Name your workbook:

TripleFHealthClub & your firstname &lastname.XLSX

e.g. TripleFHealthClub*LucaPacioli*.XLSX

In this assignment, you will create the following sheets:

* Worksheets: AlgebraicModel, RelevantTables can create now
* Chart Sheets: only created when you get to that stage of the assignment when you need a chart.



To Create Chart Sheets Review the Microsoft Help

<https://support.office.com/en-us/article/Create-a-chart-from-start-to-finish-0baf399e-dd61-4e18-8a73-b3fd5d5680c2>

**Required:**

1. Project the membership for the years 2018 and 2019 using Excel Exponential Smoothing (ETS) algorithms. Also project the 95% confidence limits of the membership projection.
2. Prepare a table for an empirical probability density function for the membership fee to use in your MCS model. Hint:

|  |  |  |  |
| --- | --- | --- | --- |
|  | Membership Fee | PDF | CDF |
| Current membership fee | $45.00 |  |  |
| Increase to most likely | $50.00 |  |  |
| Increase to a maximum of | $55.00 |  |  |

This empirical probability density is best handled in Excel with an IF statement.

1. Using Members as the independent variable, estimate (using Excel LINEST) the variable and fixed costs for:

Regular employees' wages and benefits

Lesson and class employees' wages and benefits

Towels and supplies

Utilities (heat and light)

Assume the following cash flows are fixed:

Manager's salary and benefits

Miscellaneous

Mortgage interest – no pdf

Mortgage principal – no pdf

Planned equipment purchases

1. Based on a previous (not shown here) data analysis the following correlation matrix was determined:

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
|  | Members | Annual Fee | Lesson and class fees | Towels and supplies |
| Members | 1 |  |  |  |
| Annual Fee | -0.80 | 1 |  |  |
| Lesson and class fees | 0.85 | -0.60 | 1 |  |
| Towels and supplies | 0.85 | -0.60 | 0.50 | 1 |

1. Create your Monte Carlo Simulation model. Here is my model layout to assist you.



For the assumption variables shown below, use the following probability density functions:

|  |  |
| --- | --- |
| **Assumption Variable** | **Probability Density Function** |
| Members | Triangular |
| Annual Fee | Empirical |
| Lesson & class fees | Triangular |
| Miscellaneous | Uniform |
|  |  |
| Manager’s salary and benefits | Uniform |
| Regular employees | Normal for variable cost and Uniform for fixed costs |
| Lesson and class employees | Normal for variable cost and Uniform for fixed costs |
| Towels and supplies | Normal for variable cost and Triangular for fixed costs |
| Utilities (heat and lights) | Normal for variable cost and Triangular for fixed costs |
| Miscellaneous | Uniform |
| Mortgage interest | Fixed cost, no pdf |
| Mortgage principal | Fixed cost, no pdf |
| Planned equipment purchases | Triangular |

1. Prepare the deterministic cash flow statement for 2018 – use the following as a model. Locate your table on the RelevantTables sheet.



1. Summarize your MCS results with relevant statistics. Use the following as a model. Locate your table on the RelevantTables sheet.



1. Prepare the following chart sheets:

|  |  |  |
| --- | --- | --- |
| **Chart sheet** | **Content** | **Comment** |
| Forecast | The past membership for 2010 to 2017 and your forecast for 2018 and 2019. |  |
| Regression | Regular employees' wages and benefits | Only present this one regression chart. If you do this correctly obviously you could chart all other expenses. |
| PDF | 2018 Net Cash Flow | Suggest 17 bins |
| CDF | 2018 Net Cash Flow |  |
| Tornado | 2018 Net Cash Flow |  |

1. Will the board have adequate funds to purchase the new exercise equipment next year? Support your answer with a sentence or two of explanation.
2. Will the board be able to save an “adequate chunk of funds” to buy the adjoining property in 5 years? Support your answer with a sentence or two of explanation.

To Create Chart Sheets Review the Microsoft Help

<https://support.office.com/en-us/article/Create-a-chart-from-start-to-finish-0baf399e-dd61-4e18-8a73-b3fd5d5680c2>

**Get the Data Ready**

1. Forecast the membership at TRIPLE-F HEALTH CLUB for the next 2 years (24 months). Use the data in Exhibit 1.
   1. Use the Excel FORECAST.ETS function to forecast the membership for the next 2 years.
      1. Excel FORECAST.ETS function parameters:
      2. Seasonality assume 1
      3. Data completion assume 1
      4. Aggregation assume 1
   2. Use the Excel FORECAST.ETS.CONFINT function to return the 95% confidence interval for each forecast value. Generate both the + and – 95% confidence intervals.
      1. Excel FORECAST.ETS.CONFINT function parameters:
      2. Confidence level assume 0.95
      3. Seasonality assume 1
      4. Data completion assume 1
      5. Aggregation assume 1
2. Prepare a chart (scatter with smooth lines) of your Exhibit 1 data and your forecast and confidence interval data. Create the chart as a separate chart sheet. Use your creative skills to make the chart cosmetically appealing.
3. Using the Membership fees data in Exhibit 2:
   1. Create the cumulative density function (CDF).
4. Using the Lesson and Class fees and Miscellaneous data in Exhibit 3:
   1. Create a table of the values provided.









1. Using the data in Exhibit 5 create the following linear regression models. Use LINEST for the regressions. If you are unsure of the LINEST output use F1 help to review LINEST. LINEST will estimate a & b in the linear model   
   Y = aX + b
   1. Regular employees’ wages and benefits as a function of actual members.  
      Employees’ Wages and Benefits = a \* Actual Members + b  
      Use LINEST to estimate a and b

|  |  |  |
| --- | --- | --- |
| Range | Formula | Comment |
| D38:E42 | =LINEST(E28:E35,C28:C35,TRUE,TRUE) | The Excel function LINEST for linear regression |
| C38 | =D38-D39 | The coefficient estimate minus the standard error of the estimate. |
| C39 | =D38+D39 | The coefficient estimate plus the standard error of the estimate. |
| C40 | =SQRT(C38^2+D38^2+C39^2-C38\*D38-C38\*C39-D38\*C39) | Standard deviation for a triangular distribution, assuming C38 min, C39 max, D38 the mode. |
| F38 | =E38-E39 | Repeat C38 to C40, the variable cost coefficient for b, the fixed cost coefficient. |
| F39 | =E38+E39 |
| F40 | =SQRT(E38^2+F38^2+F39^2-E38\*F38-E38\*F39-F38\*F39) |
| D43 | =D38/D39 | *t* value |
| E43 | =T.INV(0.95,E41) | Calculated threshold for the *t* value. |

1. Repeat the LINEST process for:
   1. Lesson and Class Employees’ Wages and Benefits
   2. Towels and Supplies
   3. Utilities (heat and light)
2. Prepare a chart (scatter) of the *Employees’ Wages and Benefits* and the *Actual Members*.
   1. Add a linear trendline to your chart; check the boxes “Display Equation on chart” and “Display R-squared value on chart”. Create the chart as a separate chart sheet. Use your creative skills to make the chart cosmetically appealing.
3. Using the LINEST results from steps 5 and 6 prepare a summary table of the assumption variables.
4. Create a table of the data in Exhibit 6.
5. Create a table of the data in Exhibit 4.











**Prepare the Monte Carlo simulation model and reports (tables and charts)**

1. Prepare a correlation matrix for the correlations between:  
   Members  
   Annual Fee  
   Lesson and class fees  
   Towels and supplies  
   The data for the correlation matrix is in question 4.
2. In cell C76 enter the formula =MDETERM(C71:F74) This is the determinant of the correlation matrix. The determinant must be positive for the Cholesky algorithm to work.
3. Prepare the MCS data:
4. Make sure you have the MCSLibrary.XLSM file open and available for your MCS model.
5. Select cell A92 and enter the caption as per the image.
6. Select range A93:D93 and enter the array formula =MCSLibrary.xlsm!CorrelatedUniform($C$71:$F$74)

This formula will pass the correlation matrix to the Cholesky algorithm. And return correlated uniform random values [U(0,1)] with the predetermined correlations.

1. Copy the array formula from A93:D93 down to row 10092 i.e. 10,000 rows. Effectively a Monte Carlo simulation model with 10,000 iterations. You may test the validity of the Cholesky algorithm.
   1. Select cell C79 and enter the correlation formulas for the values being returned from the Cholesky algorithm.

|  |  |
| --- | --- |
| Cell | Formula |
| C79 | =CORREL(A93:A10092,B93:B10092) |
| C80 | =CORREL(A93:A10092,C93:C10092) |
| C81 | =CORREL(A93:A10092,D93:D10092) |
| D80 | =CORREL(B93:B10092,C93:C10092) |
| D81 | =CORREL(B93:B10092,D93:D10092) |
| E81 | =CORREL(C93:C10092,D93:D10092) |

* 1. Select Formulas -> Calculation -> Calculate Now and notice the values for the correlation formulas closely match the correlation matrix. These correlated uniform random values will now be used in the probability density function assumption formulas below.







1. Select cell F90 and enter the captions as per the image.
2. Select the appropriate cell – enter the following formulas.

|  |  |
| --- | --- |
| Cell | Formula |
| F93 | =MCSLibrary.xlsm!TriangularRnd(A93,$D$12,$E$12,$F$12) |
| G93 | =IF(B93<=$I$16,$E$16,IF(B93<=$I$17,$E$17,$E$18)) |
| H93 | =F93\*G93 |
| I93 | =MCSLibrary.xlsm!TriangularRnd(C93,$E$21,$F$21,$G$21)\*H93 |
| J93 | =MCSLibrary.xlsm!Uniform($E$22,$F$22) |
| K93 | =H93+I93+J93 |

1. Copy the formulas to row 10092 i.e. 10,000 iterations.
2. Select cell L90 and enter the captions as per the image.
3. Select the appropriate cell – enter the following formulas.

|  |  |
| --- | --- |
| Cell | Formula |
| L93 | =MCSLibrary.xlsm!Uniform($H$47,$J$47) |
| M93 | =NORM.INV(RAND(),$F$49,$G$49)\*F93+MCSLibrary.xlsm!Uniform($H$50,$J$50) |
| N93 | =NORM.INV(RAND(),$F$52,$G$52)\*F93+MCSLibrary.xlsm!Uniform($H$53,$J$53) |
| O93 | =NORM.INV(D93,$P$48,$Q$48)\*F93+MCSLibrary.xlsm!TriangularRnd(D93,$R$49,$S$49,$T$49) |
| P93 | =NORM.INV(RAND(),$P$51,$Q$51)\*F93+MCSLibrary.xlsm!Triangular($R$52,$S$52,$T$52) |
| Q93 | =MCSLibrary.xlsm!Uniform($R$54,$T$54) |
| R93 | =SUM(L93:Q93) |

1. Copy the formulas to row 10092 i.e. 10,000 iterations.
2. Select cell S90 and enter the captions as per the image.
3. Select the appropriate cell – enter the following formulas.

|  |  |
| --- | --- |
| Cell | Formula |
| S93 | =INT(K93-R93) |
| T93 | =$G$59\*$G$57 |
| U93 | =$G$58 |
| V93 | =MCSLibrary.xlsm!Triangular($E$62,$E$63,$E$64) |
| W93 | =INT(S93-T93-U93-V93) |

1. Copy the formulas to row 10092 i.e. 10,000 iterations.







The MCS model should now appear as follows.





1. Create the following tables for the relevant charts.
   1. PDF & CDF tables. Use the captions as per the image.
      1. Bins – create 17 bins anchored by the minimum and maximum values in the *2018 Net Cash Flow*
      2. Use FREQUENCY() to count the number of *2018 Net Cash Flow* within the Bins.
      3. Create the PDF of the frequency.
      4. Create the CDF of the frequency.

|  |  |  |
| --- | --- | --- |
| Cell | Formula | Comment |
| Y93 | =MIN(W93:W10092) |  |
| Y109 | =MAX(W93:W10092) |  |
| Y94 | =Y93+($Y$109-$Y$93)/16 | Copy formula from row 94 to row 109 |
| Z93:Z109 | =FREQUENCY(W93:W10092,Y93:Y109) | Entered as an array formula |
| AA93 | =Z93/$Z$110 | Copy formula to row 109 |
| AB93 | =AA93 |  |
| AB94 | =AB93+AA94 | Copy formula to row 109 |
| Z110 | =SUM(Z93:Z109) | Notice sums to 10,000 the number of iterations. |
| AA110 | =SUM(AA93:AA109) | Sums to 1, the area under the probability density function. |

* 1. Tornado chart data *2018 Net Cash Flow*. Use the captions as per the image.
     1. Sequence - enter values 1 to 11, for the 11 PDFs in the MCS model
     2. Assumption - enter the assumption descriptions
     3. Correl - use CORREL() to determine the correlation between the assumption and the *2018 Net Cash Flow*
     4. Absolute use ABS() to determine the absolute value for the CORREL()
     5. Sort the correlation data:
        1. RANK()
        2. INDEX(), MATCH() to reorder the sorted data

|  |  |  |
| --- | --- | --- |
| Cell | Formula | Comment |
| AA114 | =CORREL($F$93:$F$10092,$W$93:$W$10092) | Create similar formulas for rows 115 to 124 |
| AB114 | =ABS(AA114) |
| AC114 | =RANK(AB114,$AB$114:$AB$124,1) |
| AD114 | =INDEX($Z$114:$Z$124,MATCH(Y114,$AC$114:$AC$124,0)) |
| AE114 | =INDEX($AA$114:$AA$124,MATCH(Y114,$AC$114:$AC$124,0)) |





**Prepare the deterministic information**

1. Insert RelevantTables worksheet.
2. Prepare a budgeted *2018 Net Cash Flow*.
3. Using the RelevantTables worksheet
   1. Prepare a table of descriptive statistics *2018 Net Cash Flow*. Use Excel functions: AVERAGE, MEDIAN, MODE, STDEV.S, VAR.S, KURT, SKEW, MIN, MAX, SUM, COUNT
   2. Prepare a table Relevant Probabilities

|  |  |
| --- | --- |
| Descriptive Term | Use Excel Functions |
| Probability of deterministic cumulative cash flow | =F26  =INDEX(AlgebraicModel!AA93:AA109,MATCH(F26,AlgebraicModel!Y93:Y109,1)) |
| nearest PDF match | =INDEX(AlgebraicModel!Y93:Y109,MATCH(MIN(ABS(AlgebraicModel!Y93:Y109-F26)),ABS(AlgebraicModel!Y93:Y109-F26),0)) enter as array formula |
| Probability at least | =F26  =COUNTIFS(AlgebraicModel!$W$93:$W$10092,"<="&K37)/D46 |
| Probability greater than | =F26  =COUNTIFS(AlgebraicModel!$W$93:$W$10092,">"&K38)/D46 |
| Pareto 80/20 rule | =INDEX(AlgebraicModel!Y93:Y109,MATCH(80%,AlgebraicModel!AB93:AB109,1))+(80%-INDEX(AlgebraicModel!AB93:AB109,MATCH(80%,AlgebraicModel!AB93:AB109,1)))\*(INDEX(AlgebraicModel!Y93:Y109,MATCH(80%,AlgebraicModel!AB93:AB109,1)+1)-INDEX(AlgebraicModel!Y93:Y109,MATCH(80%,AlgebraicModel!AB93:AB109,1)))/(INDEX(AlgebraicModel!AB93:AB109,MATCH(80%,AlgebraicModel!AB93:AB109,1)+1)-INDEX(AlgebraicModel!AB93:AB109,MATCH(80%,AlgebraicModel!AB93:AB109,1)))  80% |
| Probability will not have positive "2018 Net Cash Flow" | =COUNTIF(AlgebraicModel!$W$93:$W$10092,"<=0")/D46 |
| Probability will have positive "2018 Net Cash Flow" | =COUNTIF(AlgebraicModel!$W$93:$W$10092,">0")/D46 |
| Probability "2018 Net Cash Flow" within range  deterministic range | =COUNTIFS(AlgebraicModel!$W$93:$W$10092,">"&J46,AlgebraicModel!$W$93:$W$10092,"<="&L46)/D46 |
| MCS expected mean | =COUNTIFS(AlgebraicModel!$W$93:$W$10092,">"&J47,AlgebraicModel!$W$93:$W$10092,"<="&L47)/D46 |







1. Prepare a probability density function of the *2018 Net Cash Flow* - create the chart (clustered column) as a separate chart sheet. Use your creative skills to make the chart cosmetically appealing.
2. Prepare a cumulative density function of the *2018 Net Cash Flow* - create the chart (scatter with smooth lines) as a separate chart sheet. Use your creative skills to make the chart cosmetically appealing.
3. Prepare a Tornado chart of the *2018 Net Cash Flow* - create the chart (clustered bar) as a separate chart sheet. Use your creative skills to make the chart cosmetically appealing.





